libfprint-fpcmoh-git/PKGBUILD

pkgname=libfprint-fpcmoh-git
_pkgname=libfprint
pkgver=1.94.8
pkgrel=1
pkgdesc="libfprint with proprietary FPC match on host device 10a5:9800 driver"
url="https://fprint.freedesktop.org/"
arch=(x86_64)
license=(LGPL)
depends=(libgusb pixman nss systemd-libs)
makedepends=(git meson gtk-doc gobject-introspection systemd patchelf)
provides=("libfprint=$pkgver" libfprint-2.so libfpcbep.so)
conflicts=(libfprint)
groups=(fprint)
source=(
    "git+https://gitlab.freedesktop.org/libfprint/libfprint.git#tag=v1.94.8"
    "fpcbep.zip::https://download.lenovo.com/pccbbs/mobiles/r1slm01w.zip"
)
sha256sums=(
    'SKIP'
    'c7290f2a70d48f7bdd09bee985534d3511ec00d091887b07f81cf1e08f74c145'
)

prepare() {
    libfpcbep_path=$(find . -name 'libfpcbep.so')
    cp -f $libfpcbep_path $_pkgname
    cd $_pkgname
    # patch meson.build
    # use '+' as sed delimiter 
    sed -ibak "s+find_library[(]'fpcbep', required: true[)]+find_library('fpcbep', required: true, dirs: \'$(pwd)\')+g" ./meson.build
}

build() {
    arch-meson $_pkgname build
    meson compile -C build
}

package() {
    DESTDIR="$pkgdir" meson install -C build
    install -D $srcdir/$_pkgname/libfpcbep.so $pkgdir/usr/lib/libfpcbep.so
    install -Dm644 $srcdir/FPC_driver_linux_libfprint/install_libfprint/lib/udev/rules.d/60-libfprint-2-device-fpc.rules \
        $pkgdir/usr/lib/udev/rules.d/60-libfprint-2-device-fpc.rules
    cd $pkgdir/usr/lib
    libfpcbep_needed=$(ldd libfprint-2.so | grep libfpcbep | sed 's/[(].*[)]//g')
    patchelf --replace-needed $libfpcbep_needed libfpcbep.so libfprint-2.so
}